#336 Microsoft Wedge Mobile Keyboard のFキーをFnキー無しで動作させる 

Microsoft Wedge Mobile Keyboard(ウェッジ モバイル キーボード)を使っているのですが、Fキー(ファンクションキー)はFnキーを押しながら使う仕様なので漢字変換などが使い難いのです。使用頻度が高いとは思えないWindows 8のショートカットをキーに割り当てるなんてどうかしてます。漢字変換でFキーは使用しますから、日本語環境を考えるとFキーと逆にすべきですよね。米国ではFキーはあまり使わないんでしょうか。


どう考えてもこのFキーの仕様は使いやすいとは思えないので、キーの割り当てを変更してFnキー無しでファンクションキーが動作するようにしてみました。


こういったことには定番らしいAutoHotKeyというソフトを使用します。ネットで検索するとこのソフトを使ってWedge Mobile KeyboardのFキーの割り当てを変更している方もいらっしゃったのですが、公開されているコードではうまく動作しないので独自にスクリプトを作成しました。AutoHotKeyとこのスクリプトを組み込むことでFnキー無しでFキーを使用することができます。良かったらご利用ください。


マイクロソフト ワイヤレス Bluetooth キーボード Wedge Mobile Keyboard U6R-00022

2015/8/14 最新版ver.3.0を公開しました。
・F5~F8キーが動作しない場合がある件に対応しました。
・その他、音量調整機能の追加や、通常版とカスタム版2種類の機能を統一するなど内容を全面的に見直しました。

実行形式(EXE)での配布を追加しました。実行形式のファイルを使うと、面倒なソフトのインストールやスクリプトの組み込みが不要です。詳しくは、「実行形式のスクリプトファイルの配布」をご覧ください。



<このスクリプトで出来ること>
Wedge Mobile Keyboardのファンクションキーの機能を逆転させます。Fnキー無しでキーを押した場合はファンクションキーとして動作させ、Fnキーと同時に使用することで元の機能(Windows8のショートカット等)を動作させます。
・Fnキー無しでファンクションキーを動作させる
・Fnキーと併用することで、元の機能を動作させる


<導入方法>
AutoHotKeyをインストールし、このスクリプトをコピー&ペーストで貼り付けて使用します。EXE(実行形式)を使用する場合はutoHotKeyのインストールは不要です。
※スクリプトは2種類公開しています。どちらかお好みのものをご利用ください。
ソフトはAutoHotKeyの公式版を使用しています。派生版であるAutoHotKey_Lでの動作はver.2.0のスクリプトでは確認しています。

AutoHotKey v1.1系の場合(ver.1.1.22.02にて確認)
AutoHotKey v1.1からはデフォルトのスクリプトファイルが自動的に作られなくなりました。この為、プログラムを起動するとヘルプが表示されます。今後仕様が変更される可能性もありますが、プログラムを実行してもヘルプが表示される場合は、次の方法を試してください。
1.AutoHotKeyをダウンロードしてインスト-ルする(インストール時の選択はExpress Installationで良いでしょう)
2.マイドキュメントフォルダを開く(ライブラリ>ドキュメントで良い)
3.新規作成からAutoHotKey Scriptを選択する
4.ファイル名をAutoHotkey.ahkとします(拡張子を表示させていない場合は、AutoHotkeyとしてください)
5.AutoHotkey.ahkを右クリックし、Edit Scriptを選択する(Edit Scriptが選択できない場合はメモ帳で開いてください)
6.AutoHotkey.ahkがメモ帳等で開くので、中身を全部消す
7.このスクリプトを張り付けてメモ帳を保存する
8.AutoHotKeyを起動する(スタートメニューから起動します)

旧バージョンのAutoHotKey(ver.1.0系) または AutoHotKey_L v1.1.18.00の場合
1.AutoHotKeyをダウンロードしてインスト-ルする
2.AutoHotKeyを起動する
3.通知領域の緑色のHマークのアイコンを右クリックし、Edit This Scriptを選ぶ
4.AutoHotkey.ahkがメモ帳で開くので、中身を全部消す(内容は意味の無いサンプルコードです)
5.このスクリプトを張り付けてメモ帳を保存する
6.AutoHotKeyを終了して起動しなおす。Reload This Scriptでも良い。
AutoHotKeyをスタートアップに登録しておくと便利かもしれません。


<スクリプト(通常版)>

; Microsoft Wedge Mobile Keyboard Fキー置き換えスクリプト【通常版】
; 機能
;     Fキーに割り当てられているWindows8の機能とFキーの機能を逆転させます
;       通常はFキーして動作し、Fnキーと同時に押すと元のショートカット機能が機能します
;     その他の機能
;      ・Win+Del Insertキーとして機能します。
;      ・音量ボタン(上・下)+画面タッチでボリューム調整が機能します。
;     カスタム版の機能(カスタム版はF10-F12の扱いを変更したバージョンです)
;      ・Home, End, PgUpキー 刻印通りの機能が働きます
;      ・ファンクションキー F1-F9はFnキー不要、F10-F12はFnキーと同時押し
; 作成      zze128.blog9.fc2.com
; 版数      ver.3.0
; 2015/08/14 3.0 通常版・カスタム版の機能、ソースコード、版数を統一した。通常版とカスタム版は区分で切り替える。
;           仕様違いの Wedge Mobile Keyboardに対応した(F5~F8のキーの動作が異なる個体がある)。
;           F5~F8キーの判定ロジックを見直し "if 変数 in 値" で判定することとした。
;           通常版にInsertキー機能に対応 Win+Del
;           ボリューム調整機能を追加した 音量ボタン(上・下)+画面タッチ(試験的に公開)
;           ver.3.0制作協力 つっき様
; 2015/01/13  カスタム版2.1 無変換キーを使用していた機能を廃止。Insertキー機能はWin+Delに変更。
; 2015/01/03  カスタム版2.0 初期バージョン
; 2014/12/22  通常版1.0 初期バージョン
; 動作環境
;     Microsoft Wedge Mobile Keyboardに対応しています(U6R-00022, U7R-00022)。
;     AutoHotKey v1.1.22.03用のスクリプトです。AutoHotKey ver.1.0系やAutoHotKey_Lでも動作するかもしれません。
; 制限
;     Microsoft Wedge Mobile KeyboardにはF5-F8の内部動作が異なる2種類のタイプが存在します。
;       タイプA F5-F8キーにF21と修飾キーの組合わせが割り当てられている 例)F5=左Shift+左Windows+F21
;       タイプB F5-F8キーにショートカットが割り当てられている 例)F5=Windows+Q
;     タイプAの場合、F5-F8とCtrl等の修飾キーが併用できません。他のFキーには制限はありません。
;     タイプAの場合、F5-F8でCtrl等の修飾キーを併用した場合、他のFキーとして動作する可能性があります。例)Ctrl+F8でF7として動作する
;     マルチメディア機能をFキーに置き換えている為、ボリューム調整などPC本体のマルチメディア系のボタンが正しく働かない可能性があります。
;     Windows 8.x、10の一部ショートカットが動作しません。Windowsキー+Q, H, K, IはFキーとして動作します。
; 参考
;     修飾キーの説明 ^:Ctrl +:Shift !:Alt #:Windowsキー <:左 *:修飾キー併用可

;Auto-execute セクション 定数の設定
varMode = 0				;通常版・カスタム版の設定 0:通常版 1:カスタム版

;タイプA
varKeyF5 = +<#F21		;Shift 左Win F21
varKeyF8 = <#F21		;左Win F21
varKeyF6 = !<#F21		;ALT 左Win F21
varKeyF7 = ^<#F21		;Ctrl 左Win F21

;タイプB
varKeyF5x = *#q		;Win Q
varKeyF6x = *#h		;Win H
varKeyF7x = *#k		;Win K
varKeyF8x = *#i		;Win I

Return

;Fキーのリマップ
Media_Play_Pause::F1
Volume_Mute::F2
Volume_Down::F3
Volume_Up::F4

PrintScreen::F9

#If varMode = 0		;通常版・カスタム版の制御
Home::F10
End::F11
PgUp::F12
#If

;F5, F8とF6, F7の処理 単純にリマップすると、他のキーが発動する件に対処
+<#F21::	;F5 タイプA 修飾キー併用不可
<#F21::		;F8
!<#F21::	;F6
^<#F21::	;F7
*#q::		;F5 タイプB 修飾キー併用可(*指定)
*#h::		;F6
*#k::		;F7
*#i::		;F8
{
	varSavHkey = %A_ThisHotkey%		;キー退避

	;タイプBの場合Blindを付ける
	blindStr =		;空の値(メモリの開放) たぶん:=""と同じ
	if varSavHkey in %varKeyF5x%,%varKeyF6x%,%varKeyF7x%,%varKeyF8x%
	{
		blindStr = {Blind}
	}

	;押されたキーの判定
	if varSavHkey in %varKeyF5%,%varKeyF5x%
	{
		Send, %blindStr%{F5}
	}
	else if varSavHkey in %varKeyF8%,%varKeyF8x%
	{
		Send, %blindStr%{F8}
	}
	else if varSavHkey in %varKeyF6%,%varKeyF6x%
	{
		Send, %blindStr%{F6}
	}
	else if varSavHkey in %varKeyF7%,%varKeyF7x%
	{
		Send, %blindStr%{F7}
	}
	else
	{
		msgbox, AutoHotKey Script miss!!
	}

	Return
}

;ホットキー(コンビネーションキー)
~LWin & Delete::		;Win DeleteでInsert
{
	Send, {Blind}{Insert}
	Return
}

Volume_Up & LButton::Send,{Volume_Up}		;VolUpを押しながら画面タッチ 音量アップ
Volume_Down & LButton::Send,{Volume_Down}		;VolUpを押しながら画面タッチ 音量ダウン

;Fキーのリマップ Fnと同時押し
F1::Media_Play_Pause
F2::Volume_Mute
F3::Volume_Down
F4::Volume_Up

F5::#q		;F5-F8はキーを送るのではなく、Window8.1のショートカットを指定
F6::#h
F7::#k
F8::#i

F9::PrintScreen

#If varMode = 0		;通常版・カスタム版の制御
F10::Home
F11::End
F12::PgUp
#If

<通常版 解説>
Fキーに割り当てられているWindows8の機能とFキーの機能を逆転させます。
キーを単独で押すとFキーとして動作し、Fnキーと同時に押すとWindows8のショートカット機能が機能します。
その他の機能
・Windowsキー+Delキー Insertキーとして機能します。
・音量ボタン(上・下)+画面タッチでボリューム調整が機能します。タブレットPC等で使用する場合、本プログラム動作中はPC本体の音量ボタンが効きませんが、音量ボタンを押しながら画面をタッチすることで音量調整を可能としました。

AutoHotKeyは今回の件で少し勉強しただけですので、おかしなことをしているかもしれません。ご了承の上ご利用ください。




<スクリプト(カスタム版)>

カスタム版は、通常版に少し手を加えたスクリプトです。Home, End, PgUpがキーボードの刻印通りの機能が働きます。

; Microsoft Wedge Mobile Keyboard Fキー置き換えスクリプト【カスタム版】
; 機能
;     Fキーに割り当てられているWindows8の機能とFキーの機能を逆転させます
;       通常はFキーして動作し、Fnキーと同時に押すと元のショートカット機能が機能します
;     その他の機能
;      ・Win+Del Insertキーとして機能します。
;      ・音量ボタン(上・下)+画面タッチでボリューム調整が機能します。
;     カスタム版の機能(カスタム版はF10-F12の扱いを変更したバージョンです)
;      ・Home, End, PgUpキー 刻印通りの機能が働きます
;      ・ファンクションキー F1-F9はFnキー不要、F10-F12はFnキーと同時押し
; 作成      zze128.blog9.fc2.com
; 版数      ver.3.0
; 2015/08/14 3.0 通常版・カスタム版の機能、ソースコード、版数を統一した。通常版とカスタム版は区分で切り替える。
;           仕様違いの Wedge Mobile Keyboardに対応した(F5~F8のキーの動作が異なる個体がある)。
;           F5~F8キーの判定ロジックを見直し "if 変数 in 値" で判定することとした。
;           通常版にInsertキー機能に対応 Win+Del
;           ボリューム調整機能を追加した 音量ボタン(上・下)+画面タッチ(試験的に公開)
;           ver.3.0制作協力 つっき様
; 2015/01/13  カスタム版2.1 無変換キーを使用していた機能を廃止。Insertキー機能はWin+Delに変更。
; 2015/01/03  カスタム版2.0 初期バージョン
; 2014/12/22  通常版1.0 初期バージョン
; 動作環境
;     Microsoft Wedge Mobile Keyboardに対応しています(U6R-00022, U7R-00022)。
;     AutoHotKey v1.1.22.03用のスクリプトです。AutoHotKey ver.1.0系やAutoHotKey_Lでも動作するかもしれません。
; 制限
;     Microsoft Wedge Mobile KeyboardにはF5-F8の内部動作が異なる2種類のタイプが存在します。
;       タイプA F5-F8キーにF21と修飾キーの組合わせが割り当てられている 例)F5=左Shift+左Windows+F21
;       タイプB F5-F8キーにショートカットが割り当てられている 例)F5=Windows+Q
;     タイプAの場合、F5-F8とCtrl等の修飾キーが併用できません。他のFキーには制限はありません。
;     タイプAの場合、F5-F8でCtrl等の修飾キーを併用した場合、他のFキーとして動作する可能性があります。例)Ctrl+F8でF7として動作する
;     マルチメディア機能をFキーに置き換えている為、ボリューム調整などPC本体のマルチメディア系のボタンが正しく働かない可能性があります。
;     Windows 8.x、10の一部ショートカットが動作しません。Windowsキー+Q, H, K, IはFキーとして動作します。
; 参考
;     修飾キーの説明 ^:Ctrl +:Shift !:Alt #:Windowsキー <:左 *:修飾キー併用可

;Auto-execute セクション 定数の設定
varMode = 1				;通常版・カスタム版の設定 0:通常版 1:カスタム版

;タイプA
varKeyF5 = +<#F21		;Shift 左Win F21
varKeyF8 = <#F21		;左Win F21
varKeyF6 = !<#F21		;ALT 左Win F21
varKeyF7 = ^<#F21		;Ctrl 左Win F21

;タイプB
varKeyF5x = *#q		;Win Q
varKeyF6x = *#h		;Win H
varKeyF7x = *#k		;Win K
varKeyF8x = *#i		;Win I

Return

;Fキーのリマップ
Media_Play_Pause::F1
Volume_Mute::F2
Volume_Down::F3
Volume_Up::F4

PrintScreen::F9

#If varMode = 0		;通常版・カスタム版の制御
Home::F10
End::F11
PgUp::F12
#If

;F5, F8とF6, F7の処理 単純にリマップすると、他のキーが発動する件に対処
+<#F21::	;F5 タイプA 修飾キー併用不可
<#F21::		;F8
!<#F21::	;F6
^<#F21::	;F7
*#q::		;F5 タイプB 修飾キー併用可(*指定)
*#h::		;F6
*#k::		;F7
*#i::		;F8
{
	varSavHkey = %A_ThisHotkey%		;キー退避

	;タイプBの場合Blindを付ける
	blindStr =		;空の値(メモリの開放) たぶん:=""と同じ
	if varSavHkey in %varKeyF5x%,%varKeyF6x%,%varKeyF7x%,%varKeyF8x%
	{
		blindStr = {Blind}
	}

	;押されたキーの判定
	if varSavHkey in %varKeyF5%,%varKeyF5x%
	{
		Send, %blindStr%{F5}
	}
	else if varSavHkey in %varKeyF8%,%varKeyF8x%
	{
		Send, %blindStr%{F8}
	}
	else if varSavHkey in %varKeyF6%,%varKeyF6x%
	{
		Send, %blindStr%{F6}
	}
	else if varSavHkey in %varKeyF7%,%varKeyF7x%
	{
		Send, %blindStr%{F7}
	}
	else
	{
		msgbox, AutoHotKey Script miss!!
	}

	Return
}

;ホットキー(コンビネーションキー)
~LWin & Delete::		;Win DeleteでInsert
{
	Send, {Blind}{Insert}
	Return
}

Volume_Up & LButton::Send,{Volume_Up}		;VolUpを押しながら画面タッチ 音量アップ
Volume_Down & LButton::Send,{Volume_Down}		;VolUpを押しながら画面タッチ 音量ダウン

;Fキーのリマップ Fnと同時押し
F1::Media_Play_Pause
F2::Volume_Mute
F3::Volume_Down
F4::Volume_Up

F5::#q		;F5-F8はキーを送るのではなく、Window8.1のショートカットを指定
F6::#h
F7::#k
F8::#i

F9::PrintScreen

#If varMode = 0		;通常版・カスタム版の制御
F10::Home
F11::End
F12::PgUp
#If

<カスタム版 解説>
通常版の機能はすべて備えています。通常版とのちがいは次の通り。
・Home End PgUpキー:刻印通りの機能が働きます
・ファンクションキー:F1-F9はFnキー不要、F10-F12はFnキーと同時押し




<実行形式のスクリプトファイルの配布>
実行形式(EXE)も用意しました。実行形式のファイルを使うとAutoHotKeyソフトウェアのインストールやスクリプトの組み込みは不要です。EXEを実行するだけでスクリプトが実行できます。
次のURLからzipファイルをダウンロードします。ダウンロードボタンが小さいのでよく探してください。説明文の下、広告のすぐ上にあります。
実行形式 通常版 ver.3.0 WedgeAHK.exe
実行形式 カスタム版 ver.3.0 WedgeAHKC.exe


ダウンロードしたZIPファイルの中にEXEがありますので、任意の場所に解凍してください。

EXEファイルを実行するとスクリプトが実行されます。終了する際は通知領域の緑のHマークのアイコンを終了させてください。通常版とカスタム版は同時に実行しないでください。
スタートアップに組み込んで使用することもできます。
※実行するとWindowsの警告(Windows SmartScreen)が表示されると思いますが、詳細情報から実行できます。
※旧バージョンver.1.x, 2.xとはファイル名を変更しています。


個人的にはカスタム版がお勧めですが、ダンロードの傾向を見ると通常版の方が多いですね。意外でした。


セキュリティソフトでウィルスとして検出される場合があります(2015/8/1追記)
たぶんキー操作を監視するソフトだからだと思いますが、ノートンでウィルスとして検出されます。開発した時点では検出されなかったんですが、ノートンの最近のバージョンではダウンロードした時(ダウンロードインサイト)、実行した時(SONAR)に検出されるようになりました。スキャン結果は問題が無いので、ふるまいを検知するタイプの検査にひっかかっているようです。
EXEを使用するには、スキャン対象から除外してください。ノートンの場合は検疫されたファイルを復元すればスキャン対象から除外する設定も同時にできます。EXEの使用に不安のある方はスクリプトを組み込む方式でご利用いただければと思います。

AutoHotkeyとセキュリティソフトに関しては次の記事も参考になります。
http://www.lifehacker.jp/2010/04/post_1470.html



<動作環境と制限>
次の環境で検証しています。
・AutoHotKey v1.1.22.03
・AutoHotKey_L v1.1.18.00 Unicode 32-bit(ver.3.0は未検証)
・Microsoft Wedge Mobile Keyboard (U6R-00022, U7R-00022)
・Windows 8.1 with Bing 32bit
・Lenovo Miix 2 8

制限
●Microsoft Wedge Mobile KeyboardにはF5-F8の内部動作が異なる2種類のタイプが存在します。
- タイプA F5-F8キーにF21と修飾キーの組合わせが割り当てられている 例)F5=左Shift+左Windows+F21
- タイプB F5-F8キーにショートカットが割り当てられている 例)F5=Windows+Q
- タイプAの場合、F5-F8とCtrl等の修飾キーが併用できません。他のFキーには制限はありません。
- タイプAの場合、F5-F8でCtrl等の修飾キーを併用した場合、他のFキーとして動作する可能性があります。例)Ctrl+F8でF7として動作する
●マルチメディア機能をFキーに置き換えている為、ボリューム調整などPC本体のマルチメディア系のボタンが正しく働かない可能性があります。音量調整については代替手段を用意していますので試してみてください。
●Windows 8、10の一部ショートカットが動作しません。Windowsキー+Q, H, K, IはFキーとして動作します。

※タイプA、Bの違いはどこから来るものなのかは不明です。私の所持しているU6R-00022、製造月09/2014(製造月は電池ボックス内に印字)と、U7R-00022(ビジネスモデル) 製造月08/2012を比較するとF5-F8の動作が違っていました。マイクロソフトにも問い合わせましたが、情報はありませんでした。


参考にさせていただいたサイト様
マイクロソフト Sculpt Mobile Keyboardのファンクションキーをなんとかする:Design Ambience Blog 様 マイクロソフトのキーボードですが、キーボードの制御コードが異なるようです。


Microsoft Wedge Mobile KeyboardのFnキーを(擬似的に)ロックする:ymknの日記 様
同じWedge Mobile Keyboardですが、こちらの方法ではF5からF8のキーが機能しませんでした。なにが違うんでしょうか。
(2015/8/9追記)Wedge Mobile Keyboardでも仕様が異なるものがありました。コメントでやり取りしていますが、F5~F8のコードが違うものがあるようです。

AutoHotkeyJp 様
AutoHotkeyの日本語版リファレンスです。

http://www.autohotkey.com/
公式サイト(英語)です。ソフトはここからダウンロードします。


正しく動作しないところやご要望などございましたら、ご指摘いただけると助かります。

ご利用に関して ソフトウェア等のご利用ガイド

スポンサードリンク


コメント

通知領域の緑色のHマークのアイコンが無い

安売りしていたMicrosoft Wedge Mobile Keyboard U6R-00022が昨日届いたので、Windows8.1のタブレット HP Stream7で使ったら、何これ?

英語の小文字・大文字や日本語入力の切り替えが出来ない、F7キーを押してもカタカナにならない・・・
専用のドライバーを入れないと正常動作しないのだろうと思ってマイクロソフトのホームぺージからドライバを落としてきたけど適用できない。
そこで解決方法を探したところ、管理者様のホームページを見つけました。
ところでAutoHotKeyの仕様が変わったのか、ここで紹介された方法ではスクリプトの登録は出来ないみたいです。
※通知領域の緑色のHマークのアイコンが無い。

そこでデスクトップで右クリックして新規作成、次にAutoHotKey Scriptを選択して管理者様のスクリプトを貼り付けて、新規作成したAutoHotKey Scriptをスタートアップに登録しました。

2.AutoHotKeyを起動する
3.通知領域の緑色のHマークのアイコンを右クリックし、Edit This Scriptを選ぶ

管理者様のスクリプトのおかげで楽に文字入力が出来そうです。
ありがとうございました。

Re: 通知領域の緑色のHマークのアイコンが無い

こんにちは。管理者の2ZZです。情報ありがとうございます。
試してみましたが、教えていただいたようにインストール直後のAutoHotKeyの動きが前とは違いますね。検証してから記事は修正することにします。

今回のことで思ったんですが、スクリプトの組み込みはPCに不慣れな方には難しいと思いますので、実行形式(EXE)のファイルも公開しました。記事本文に追記しています。
EXEで公開するのはセキュリティ上は良くないと思っていたのですが、今回の仕様変更のようなことがあると、EXEも用意しておいた方が良いかと考えました。

コメントされていることについて回答しますが、既にご存知の場合はスルーしてください。
>英語の小文字・大文字や日本語入力の切り替えが出来ない、F7キーを押してもカタカナにならない・・・
既にご存じかとはおもいますが、Wedge Mobile KeyboardのファンクションキーはFnキーと同時押しです。

>専用のドライバーを入れないと正常動作しないのだろうと思ってマイクロソフトのホームぺージからドライバを落としてきたけど適用できない。
このキーボード用のドライバっていうのはありませんよね。私も探しました。ファンクションキーはFnキーと同時に押すのが仕様ですので、それ以外の使い方はマイクロソフトはサポートしていません。

Re: 通知領域の緑色のHマークのアイコンが無い

通りすがり 様

原因が分かりましたので記事に追記しておきました。ver.1.1からはやはり仕様が変わったようです。ソフトもインストーラー形式に変更になっていますね。以前はZipファイルでした。

何故か英語キーボードとして認識されていました。

2ZZさん、こんにちは。

Wedge Mobile Keyboard U6R-00022の以下のページに「ソフトウェアとドライバー」として案内されています。

マウス キーボード センター 2.3 (32 ビット)
https://www.microsoft.com/hardware/ja-jp/p/wedge-mobile-keyboard#support

これをダウンロードしてインストールしても失敗します。

この返信を書いていて気が付いたのですが、何故か英語キーボードとして認識されていました。
なんだかな~
そこでドライバを強引にMicrosoft Bluetooth Mobile Keyboard 6000(106/109)に変更したら、キートップの刻印のとおりに入力することができました。
やはり専用のドライバーを提供して欲しいね。

Re: 何故か英語キーボードとして認識されていました。

通りすがり 様

こんにちは。

Wedge Mobile Keyboardのサポートのページからマウス キーボード センターがダウンロードできますね。別のページのマウス キーボード センターが対応しているキーボードの一覧には載っていないので対応していないと思っていました。

試しにマウス キーボード センターをWindows 8.1タブレットにインストールしましたが、インストールはできたものの、マウス キーボード センターではWedge Mobile Keyboardは検出しませんでした(マイクロソフト製のBluetoothマウスは検出しました)。

私見ですが、Wedge Mobile Keyboardを使うだけならマウス キーボード センターは不要と思います。説明書にも確か記載はありませんでしたし、サポートページからダウンロードできるのが間違いではないかとも思えます。私のPCは英語キーボード配列になることはありません。刻印通り入力できます。

情報ありがとうございました。

EXE版でダウンロードし、使用しました。
とくにF2はよく使うので、いちいちFnキー押しながらイライラしていましたが、めっちゃスッキリです!管理者様ありがとうございました。

Re:

my様

こんにちは。管理者の2ZZです。
お役に立てたようで良かったです。本文にも記載していましすが、EXE版はセキュリティソフトでウィルスと判定される場合があります。突然ウィルスと判定されてもびっくりされない様にお願いします。

Windows10での動作について

Windows10にてEXE版を使用しております。
一部効かないキーがあり、

F5
F6
F7
F8

あたりが効いていないようです。
他のキーは概ね使えてます。
それでも、大分キーボード操作でのイライラがなくなったので、
大変感謝しております。ありがとうございます。

個人的にはF6~F8は多用するので、
解決方法が分かると非常に助かります。

Re: Windows10での動作について

つっき 様

こんにちは。管理者の2ZZです。
試した限りでは、Windows 10でも問題ありませんでした。F5からF10キーの動作を確認しましたが、想定通り動作しました。
試しにEXEを実行していない状態でどうなるか確認していただけますか。次のように動作するはずです。

F5・・・スタートメニューが開き、検索モードに入る
F6・・・共有チャームが開く
F7・・・接続チャームが開く
F8・・・設定ウィンドウが起動する


もうひとつ教えてください。OSは32bit版ですかそれとも64bit版ですか。こちらでは32bit版Windows 10で動作確認を行っています。

Re:Re: Windows10での動作について

2ZZさま、ご回答ありがとうございます。

EXEを実行していないときの状況は以下の通りです。

F5 検索ウィンドウが表示される
F6 共有チャームが表示される
F7 接続チャームが表示される
F8 設定画面が開く

ほぼ、2ZZさまが想定されている動作と同じようです。
なお、OSは32bit(Windows8.1からのUpdate)です。

なお、デバイスマネージャ→Bluetooth→Microsoft Wedge Mobile Keyboardの
ドライババージョンが「10.0.10240.16391 2006/06/21」となっています。
あと、気になるところとしては、デバイスマネージャ→キーボードを開くと、
「HIDキーボードデバイス」が3つあったりします。

お手数をおかけしますが、何卒宜しくお願いいたします。

Re: Re:Re: Windows10での動作について

つっき 様

>なお、OSは32bit(Windows8.1からのUpdate)です。
うちの環境と同じです。

>なお、デバイスマネージャ→Bluetooth→Microsoft Wedge Mobile Keyboardの
>ドライババージョンが「10.0.10240.16391 2006/06/21」となっています。
こちらも同じです。

>あと、気になるところとしては、デバイスマネージャ→キーボードを開くと、
>「HIDキーボードデバイス」が3つあったりします。
こちらでは2つです。

****

テスト用のプログラムを作りましたので、実行してどうなるか確認してみてくれますか。
http://ux.getuploader.com/gintonic/download/47/WMTEST1.exe

ダウンロードしたexeを実行し、F5~F8のキーを押して次のように表示するか確認してください(他のexeは終了してください)
F5の場合、+<#F21 と表示する。OKを押すとPush F5と表示する。他のキーは次のようになります。
F6・・・!<#F21、Push F6
F7・・・^<#F21、Push F7
F8・・・<#F21、Push F8


Re:Re: Re:Re: Windows10での動作について

2ZZさま、テストプログラムのご提供ありがとうございます。

テスト用プログラムを実行した結果ですが、
2ZZさまの意図された表示にはならず、今まで通り、

F5 検索ウィンドウが表示される
F6 共有チャームが表示される
F7 接続チャームが表示される
F8 設定画面が開く

となってしまいました。

また、テストプログラムおよび一般提供されているプログラムとも
F5~F8に関しては、
Fnキーを押しながらでも、

Fn+F5 検索ウィンドウが表示される
Fn+F6 共有チャームが表示される
Fn+F7 接続チャームが表示される
Fn+F8 設定画面が開く

となり、Fnキーを押しても押さなくても同じ動作となってしまいました。

以上、よろしくお願いいたします。

Re: Re:Re: Re:Re: Windows10での動作について

つっき 様

テスト結果のご報告ありがとうございました。
キーボードの仕様がちがうかドライバ等の関係なのか分かりませんが、こちらのキーボードと動きが違いますね。
次の点を教えていただけますか。

確認事項
1.Windows 10にする前は正常に動いていましたか。
2.キーボードの型番を教えてください。U6R-00022のような番号で、箱に書いてあります。
3.キーボードを購入したのはいつごろですか。
4.製造月はどうなっていますか。電池ボックスの中に09/2014のような印字がたぶん製造月だと思います。
5.Microsoft マウスキーボードセンターはインストールしていますか。スタートメニューのすべてのアプリのMの項目にあります。

追加テストのお願い
別のテストプログラムを作りましたので、試してもらえますか。
今回は押しているキーがどれなのかを記録するプログラムです。Fキー等は他の公開しているプログラムのようには動作しません。
http://ux.getuploader.com/gintonic/download/50/WMTEST2.exe

操作手順
1.テストプログラムを実行する
2.マウスまたはタッチパネル操作でデスクトップ画面にする(キーボードには触れないでください)
3.スペースキーとFキーを交互に押す
 例)Space、F1、Space、F2、Space、F3、(中略)、Space、F12、Space
 デスクトップ画面で操作してください。操作中チャームを表示したり色々と画面が変わると思いますが、無視してください。
 別のキーを押すなど操作をミスした場合は、プログラムを終了してやり直してください。
4.xキーを押す(英字のエックスです)
ウィンドウが開くので、その中をコピーしてブログのコメントに貼り付けてください。次の行から最後までをコピーしてください。
VK SC Type Up/Dn Elapsed Key Window
--------------------------------------------------
20 039 d 3.98 Space
20 039 u 0.14 Space
B3 122 a d 0.13 Media_Play_Pause
B3 122 a u 0.14 Media_Play_Pause
20 039 d 0.17 Space
20 039 u 0.16 Space
AD 120 a d 0.03 Volume_Mute
AD 120 a u 0.20 Volume_Mute
20 039 d 0.20 Space
20 039 u 0.11 Space
(以下省略)
5.テストプログラムを終了する

Re:Re: Re:Re: Re:Re: Windows10での動作について

2ZZさま、こんにちは。
毎回テスト用プログラムまで作成していただき、恐縮です。

確認事項
>1.Windows 10にする前は正常に動いていましたか。
残念ながら、Windows8.1では動かしたことがありません。

>2.キーボードの型番を教えてください。U6R-00022のような番号で、箱に書いてあります。
ここが恐らく2ZZさまのものと違っていて、U7R-00022となっていました。
恐らくこれが原因かと思われます。

>3.キーボードを購入したのはいつごろですか。
2013年12月です。

>4.製造月はどうなっていますか。電池ボックスの中に09/2014のような印字がたぶん製造月だと思います。
08/2012となっていました。

>5.Microsoft マウスキーボードセンターはインストールしていますか。スタートメニューのすべてのアプリのMの項目にあります。
インストールしておりません。

追加テストは以下の通りとなりました。

VK SC Type Up/Dn Elapsed Key Window
-------------------------------------------------------------------------------------------------------------
20 039 d 4.92 Space Program Manager
20 039 u 0.13 Space
B3 122 a d 0.73 Media_Play_Pause
B3 122 a u 0.19 Media_Play_Pause
20 039 d 0.55 Space
20 039 u 0.13 Space
AD 120 a d 0.55 Volume_Mute
AD 120 a u 0.19 Volume_Mute
20 039 d 0.47 Space
20 039 u 0.14 Space
AE 12E a d 0.53 Volume_Down
AE 12E a u 0.19 Volume_Down
20 039 d 0.52 Space
20 039 u 0.16 Space
AF 130 a d 0.42 Volume_Up
AF 130 a u 0.17 Volume_Up
20 039 d 0.61 Space
20 039 u 0.13 Space
5C 15C d 0.63 RWin
51 010 d 0.00 q
5C 15C u 0.16 RWin 検索
51 010 u 0.00 q
20 039 d 0.59 Space
20 039 u 0.09 Space
5C 15C d 0.61 RWin
48 023 d 0.00 h
5C 15C u 0.17 RWin 共有
48 023 u 0.00 h
20 039 d 0.64 Space
20 039 u 0.13 Space
5C 15C d 0.55 RWin
4B 025 d 0.00 k
5C 15C u 0.17 RWin N/A
4B 025 u 0.00 k
20 039 d 0.53 Space 接続
20 039 u 0.13 Space
5C 15C d 0.55 RWin 設定
49 017 d 0.00 i
5C 15C u 0.17 RWin
49 017 u 0.00 i
20 039 d 0.67 Space
20 039 u 0.14 Space
2C 137 d 0.67 PrintScreen デバイスを追加します
2C 137 u 0.14 PrintScreen
20 039 d 0.70 Space
20 039 u 0.11 Space
24 147 d 0.64 Home
24 147 u 0.19 Home
20 039 d 0.56 Space
20 039 u 0.14 Space
23 14F d 0.59 End
23 14F u 0.14 End
20 039 d 0.61 Space
20 039 u 0.13 Space
21 149 d 0.78 PgUp
21 149 u 0.17 PgUp
20 039 d 0.63 Space
20 039 u 0.13 Space
58 02D d 0.86 x

以上、よろしくお願いいたします。

Re: Re:Re: Re:Re: Re:Re: Windows10での動作について

つっき 様

テストありがとうございます。
やはりこちらのキーボードとは一部Fキーの仕様が違いますね。型番の違いによるものか製造時期の違いなのかどちらかでしょう。
いただいたデータを元にプログラムを作ってみますが、実機がありませんので少し時間がかかるかもしれません。もしよければ、メールフォームからメールアドレスを連絡いただければ出来次第連絡させていただきます。

新しいスクリプト ver.3.0 を公開しました

こんにちは。管理者の2ZZです。

F5-F8が効かない場合がある件に対応したスクリプトを公開しました。Wedge Mobile KeyboardにはF5-F8の動作が異なるものがあるようですので、両方に対応できるように改造しました。
新機能の追加と全体的にコードを見直してしていますので、今後は新しいものを使っていただければと思います。

ご協力いただいた つっき様 ありがとうございました。

質問です

はじめまして。

こちらのキーボードのFnキーの入れ替えで検索してこちらのサイトに訪れたものです。

私の持っているものはU6R-00022、製造月04/2014でタイプAでした。管理者様のキーボードはどちらの方がタイプBだったのでしょうか。

現状使っているソフトでのキーコンビネーションで不具合がでてしまい、タイプBのものを探しており手がかりをいただければと思います。

よろしくお願いいたします。

Re: 質問です

zatsuza 様

こんにちは。
こんな感じです。製造が古いものがタイプBなのかビジネスモデルがそうなのか判断できませんね。根拠の無い予想ですが、初期の製造のものがタイプBな気がしますけど。
・私の所持しているもの U6R-00022、製造月09/2014・・タイプA
・他の方のキーボード U7R-00022(ビジネスモデル) 製造月08/2012・・・タイプB
リンク先のブログ(ymknの日記様)はタイプBでしょうね。2013年の記事です。

お使いのソフトでのキーコンビネーションの不具合とはどういったものでしょうか。私の作ったプログラムを使った場合の不具合ですか。

こちらで発生している問題の詳細

2ZZ様

ご返事ありがとうございます。
製造年月日が古いほどタイプBの可能性が高そうで、今新たに新品を購入するのはやめた方が良さそうですね。

おそらくはスクリプトではなくハードウェアの問題かと思われます。

こちらで発生しております現象について参考までにお知らせいたします。

OS Windows7 64bit Ultimate SP1
Microsoft Wedge Mobile Keyboard U6R-00022 タイプA
AutoHotKey version v1.1.22.07 Unicode 64bit
使用スクリプト version 3.0 通常版

ドキュメントフォルダより新規作成にて「AutoHotkey.ahk」を作成しEdit Script(メモ帳)よりこちらのサイトのスクリプトへ置き換えした後保存し、スタートメニューの「AutoHotkey」を実行

こちらは「Adobe Photoshop CC 2015」というアプリケーションを使用しております。この画像編集ソフトでは選択領域、またはキャンパス全体を指定した色で塗りつぶす「塗りつぶし」という機能がございます。ちなみにこちらのショートカットキーが「Shift + F5」となっておりまして、AutoHotkeyが実行された状態でもWedge Mobile KeyboardからShift + F5を押下しても実行されず、主に「F5」が実行されるか、Shiftキーを押しながらF5キーを何度か素早く押しておりますと「左Winキー」が実行されスタートメニューが表示されたりします。

Wedge Mobile Keyboard タイプAでは「Shift 左Win F21」をF5キーに置き換えされていらっしゃるようでしたので、実際のShiftキーと同時には使用できないものと想像し、タイプBのWedge Mobile Keyboardでは「Shift + F5」のショートカットが正常に出来るではないかと思い今回の質問に至った次第です。

機能はともかくとしてキーボード自体はとても気に入っているのでメインで常用できないのは残念でございます。

Re: こちらで発生している問題の詳細

zatsuza様

問題点について理解しました。ブログに記載しているようにそれはタイプAの場合の制限です。F5~F8キーは修飾キー(Shift等のキーのことです)と併用できなくしています。

>制限
>●Microsoft Wedge Mobile KeyboardにはF5-F8の内部動作が異なる2種類のタイプが存在します。
>(略)
>- タイプAの場合、F5-F8とCtrl等の修飾キーが併用できません。他のFキーには制限はありません。

Adobe Photoshop CC 2015はこちらでも所持していますが、PhotoshopでShift+F5が効けば良いだけのことですか。それに限定した対応ならできるかもしれませんが、こちらで考えてみましょうか。これだけの為にキーボードを買い換えるのももったいないことですし。
念のため確認ですが、Photoshopのショートカットを別のキーに置き換えるという方法も採れると思うのでですが、Photoshop側の設定を変更するのは不可ということでしょうか。

Re:

2ZZ様

お世話になっております。

> Adobe Photoshop CC 2015はこちらでも所持していますが、PhotoshopでShift+F5が効けば良いだけのことですか。

実は数日前にAutoHotkeyを始めたばかりでして、まだPhotoshopに限らず他のソフトウェアでの動作が確認出来ておらず、基本的に修飾キーとファンクションキーの組み合わせが多いため、1つだけ対処を行ってもまた別の問題が見つかる可能性が高いと思われます。

> 念のため確認ですが、Photoshopのショートカットを別のキーに置き換えるという方法も採れると思うのでですが、Photoshop側の設定を変更するのは不可ということでしょうか。

かなり長い間使い続けたショートカット類であるため、キーボード自体は気に入っているとはいえ使い方をこちらから譲歩するということは念頭にございません。

タイプBのものが見つかるよう気長に探したいと思います。

この度はご相談に乗ってくださいまして誠にありがとうございます。

Re: Re:

zatsuza 様

こんにちは。
修飾キーとの併用が出来ないのは私も気になっていました。これは、キーボードが発生させているコードの中に修飾キーを含んでいる為にキーを押していることが区別出来なかったり、別のショートカットと誤判定する為に設けている制限です。
キーボード右側のキー(右Shift等)との併用は出来そうに思いますので、今度時間のある時に試してみます。
また、根本的な対応ができるかどうかも併せて検討してみますが、ちょっと難しそうです。

Re:Re:Re:

2ZZ様

お世話になっております。

そもそも我々からするとファンクションキーがFnキーとのコンビネーションと言うのが信じられませんよね^^;;;

SurfaceProも持っているのですが、こちらの専用キーボード(TyepCover)も当初ファンクションキーがFnキーとの併用でしたが、後々公式より動作の入れ替えができるようになるアップデートがおこなわれ事なきをえたのですが、Wedge Mobile Keyboardではあまり期待できそうにありません。

ファンクションキーを送信するにあたり修飾キーが使われてしまっていることから、こちらをAutoHotkeyで解決することは困難と思われますので、ご検討というお気持ちだけありがたく頂戴いたします。

この問題を除けばホントに良いキーボードなんですけどね

それでは

Re: Re:Re:Re:

zatsuza 様

> ファンクションキーを送信するにあたり修飾キーが使われてしまっていることから、こちらをAutoHotkeyで解決することは困難と思われますので、ご検討というお気持ちだけありがたく頂戴いたします。
キーを押しているかどうかを判定する命令があるので検証してみたたのですが、修飾キーを押しているかどうか判定することは可能ですが、現実的な解決方法には結びつきませんでした。
F5を押している間はShiftを押していることになっていますので、実際にShiftキーを押しているかどうかはF5を離したタイミングを見計らって判定するしかありません。なので、方法としては少し(300ミリ秒ほど)待ってからキーの押し下げを判定するか、またはキーを押したときではなく離した時に判定するかといった方法を採るしかないようです。どちらの方法も使いにくくなりますので、やはり右の修飾キーのみ対応しようと思います。

> そもそも我々からするとファンクションキーがFnキーとのコンビネーションと言うのが信じられませんよね^^;;;
英語圏ではファンクションキーはあまり使わないんですかね。私にもこの仕様は理解できません。最近のMSのキーボードはこれが標準になっているようですので、日本の感覚とは違うのかもしれませんね。

Re: Re: Re:Re:Re:

zatsuza 様

こんにちは。
右の修飾キーだけでも対応できないか検討しましたが、無理でした。キーの組み合わせによってはアプリーケーション側が正しく動作しませんでした。この件に関しては現状のままとさせていただきます。
またなにかありましたら、お気軽にご相談ください。

こんにちわ。
最近、U6R-00022を購入したのですが、ファンクションキーの数字設定が使えないバカな仕様になっていたので、
(それは以前調べて知ってまして…そのせいで欲しかったU6R-00022を購入を見送った経緯があります…(汗)

こちらのソフトをDLさせてもらって快適に使用しています。
公開ありがとうございました。

Re: タイトルなし

海の古豪 様

コメントありがとうございます。
これは良いキーボードですよね。個人的には最近はこのキーボードは使うことはあまり無いのですが、便利に使っていただいているようで良かったです。

コメントの投稿

この記事に対するご意見・ご感想を募集しています。
コメント内容のみ必須入力です。それ以外は任意でご入力ください。















管理者にだけ表示を許可する(再編集はできません)

トラックバック

この記事のトラックバックURL
http://zze128.blog9.fc2.com/tb.php/403-87a80a3d